import java.nio.file.Files
import kotlin.io.path.Path
import org.siouan.frontendgradleplugin.infrastructure.gradle.InstallFrontendTask

plugins {
    kotlin("jvm") version "2.0.20"
    id("com.gradleup.shadow") version "8.3.0"
    id("org.siouan.frontend-jdk21") version "8.1.0"
    id("java")
}

group = "org.pushrbx"
version = "1.0-SNAPSHOT"
val jarBaseName = "org.pushrbx.keycloak-themes"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation(kotlin("test"))
    implementation("org.keycloak", "keycloak-client-registration-api", "25.0.4")
    implementation("dev.jcputney", "keycloak-theme-additional-info-extension", "1.1.5")
    implementation("io.phasetwo.keycloak", "keycloak-account-v1", "0.6")
}

tasks.test {
    useJUnitPlatform()
}

kotlin {
    jvmToolchain(17)
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}

tasks.withType<JavaCompile> {
    options.release.set(17) // Ensure Java compatibility with 17
}

frontend {
    nodeVersion.set("22.6.0")
    nodeInstallDirectory.set(project.layout.projectDirectory.dir(".node"))
    installScript.set("install")
    assembleScript.set("run build")
    cleanScript.set("run clean")
}

tasks {
    val themeFiles by named<InstallFrontendTask>("installFrontend") {
        val ciPlatformPresent = providers.environmentVariable("CI").isPresent()
        val lockFilePath = "${projectDir}/package-lock.json"
        val retainedMetadataFileNames: Set<String>
        if (ciPlatformPresent) {
            retainedMetadataFileNames = setOf(lockFilePath)
        } else {
            val acceptableMetadataFileNames = listOf(lockFilePath, "${projectDir}/yarn.lock")
            retainedMetadataFileNames = mutableSetOf("${projectDir}/package.json")
            for (acceptableMetadataFileName in acceptableMetadataFileNames) {
                if (Files.exists(Path(acceptableMetadataFileName))) {
                    retainedMetadataFileNames.add(acceptableMetadataFileName)
                    break
                }
            }
            outputs.file(lockFilePath).withPropertyName("lockFile")
        }

        inputs.files(retainedMetadataFileNames).withPropertyName("metadataFiles")
        outputs.dir("${projectDir}/node_modules").withPropertyName("nodeModulesDirectory")
    }

    build {
        dependsOn(themeFiles)
    }

    assemble {
        dependsOn(themeFiles)
    }

    jar {
        archiveBaseName = jarBaseName
        manifest {
            attributes["Build-Jdk-Spec"] = "21"
        }
    }

    shadowJar {
        dependencies {
            include(dependency("dev.jcputney:keycloak-theme-additional-info-extension:1.1.5"))
            include(dependency("io.phasetwo.keycloak:keycloak-account-v1:0.6"))
        }
        archiveBaseName = jarBaseName
        dependsOn(build)
    }
}